Learning Elixir - Year One

[Eiji]

@Maxximiliann

    illegal_moves_map = %{
      "Bd3" => [
        "a5",
        "b5",
        "c5",
        "d3",
        "d4",
        "d5",
        "e5",
        "f5",
        "g5",
        "h5",
        "Nd2",
        "Ba3",
        "Bb2",
        "Bc2",
        "Be3",
        "Bf4",
        "Bf5",
        "Bg5",
        "Bg6",
        "Bh6"
      ]
    }

With Elixir formatter this is better:

defmodule Example do
  @illegal_moves %{
    "Bd3" => ~w[a5 b5 c5 d3 d4 d5 e5 f5 g5 h5 Nd2 Ba3 Bb2 Bc2 Be3 Bf4 Bf5 Bg5 Bg6 Bh6]
  }
end

as that your list would not be expanded in so many lines …

@Maxximiliann

"(#{one} #{w1} #{b1} #{two} #{w2} #{b2} #{three} #{w3} #{b3} #{four} #{w4} #{b4}) "

Shorter:

"(" <> Enum.join(possible_line, " ") <> ") "

@Maxximiliann

Map.get(illegal_moves_map, "Bd3")

Optionally:

illegal_moves_map["Bd3"]

@Maxximiliann

    Enum.map(
      moves_list,
      fn [one, w1, b1, two, w2, b2, three, w3, b3, four, w4, b4] = possible_line ->
        cond do
          w1 == "e4" ->
            remove_illegal_second_moves_after_e4(possible_line)

          w1 == "d4" ->
            remove_illegal_second_moves_after_d4(possible_line)

          true ->
            "(#{one} #{w1} #{b1} #{two} #{w2} #{b2} #{three} #{w3} #{b3} #{four} #{w4} #{b4}) "
        end
      end
    )

You may use pattern matching for this like:

    Enum.map(moves_list, fn
      [_one, w1 | _rest] = possible_line when w1 in ~w[e4 d4] ->
        remove_illegal_second_moves_after(possible_line, w1)

      possible_line ->
        "(" <> Enum.join(possible_line, " ") <> ") "
    end)

@Maxximiliann

        fn moves_list ->
          Enum.zip(move_numbering, moves_list)
          |> Enum.zip(blacks_moves_list)
          |> Enum.flat_map(fn {{number, whites_move}, blacks_move} ->
            [number, whites_move, blacks_move]
          end)
        end

Much better:

        fn moves_list ->
          [move_numbering, moves_list, blacks_moves_list]
          |> Enum.zip()
          |> Enum.flat_map(&Tuple.to_list/1)
        end

@Maxximiliann

    |> scrub_moves_list()
    |> Enum.reject(&is_nil(&1))

scrub_moves_list/1 always returns list, so second Enum.reject/2 is not needed.

Also you can write &is_nil/1.

Finally having "(" <> Enum.join(possible_line, " ") <> ") " multiple times we may want to create a helper function for that.