# Serializing Ash Structs with Jason

**URL:** <https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654>\
**Category:** Questions\
**Tags:** troubleshooting, liveview, ash\
**Created:** [October 3, 2023, 10:25am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654 "2023-10-03T10:25:23Z")\
**Posts on this page:** 14\
**Page:** 1

<div class="post-metadata">

**Author:** ![morfertaw](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/morfertaw/32/32062_2.png) [@morfertaw](https://forum.elixirforum.com/u/morfertaw)\
**Post date:** [October 3, 2023, 10:25am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/1 "2023-10-03T10:25:23Z")

</div>

So I am using [live\_svelte](https://github.com/woutdp/live_svelte) which lets you use svelte in your live\_views. You pass in the props to the svelte component in a h\_sigil and live\_svelte serializer them using Jason. Is it possible to derive the encoder for ash resource structs?

---

<div class="post-metadata">

**Author:** ![morfertaw](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/morfertaw/32/32062_2.png) [@morfertaw](https://forum.elixirforum.com/u/morfertaw)\
**Post date:** [October 3, 2023, 10:43am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/2 "2023-10-03T10:43:23Z")

</div>

I am currently manually implementing Jason.Encoder. Is there a means to derive the encoder for ash resources?

```elixir
defimpl Jason.Encoder, for: Flame.App.Reactant do
  def encode(value, opts) do
    Jason.Encode.map(Map.take(value, [:id, :identity, :spec]), opts)
  end
end

```

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [October 3, 2023, 1:56pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/3 "2023-10-03T13:56:27Z")

</div>

I think I’d actually suggest not using a protocol-based encoder, primarily because with Ash resources you can have calculations/aggregates/metadata that you may want to display along with the resource. For instance, if you wanted to show related data, or if you wanted to show computed properties, you might want something like this:

```elixir
def encode(resources, opts \\ []) do
  Jason.encode!(sanitize(resources, opts))
end

defp sanitize(records, opts) when is_list(resources) do
  Enum.map(records, &sanitize(&1, opts))
end

defp sanitize(%resource{} = record, opts) do
  if Ash.Resource.Info.resource?(resource) do
    fields = opts[:fields] || public_attributes(record)

    Map.new(fields, fn
      {field, further} ->
        {field, sanitize(Map.get(record, field), further)} 
      field -> 
        {field, sanitize(Map.get(record, field), [])} 
      end)
  else
    record
  end
end

defp sanitize(value, _), do: value

defp public_attributes(%resource{}), do: resource |> Ash.Resource.Info.public_attributes() |> Enum.map(&(&1.name))

```

Something like the above would let you call `encode(record, fields: [:field1, :field2, relationship: [fields: [:field3]])`.

This lets you load data and serialize it, i.e

```elixir
MyResource
|> Ash.Query.load([:field1, :field2, relationship: [:field3]])
|> MyApi.read!()
|> Encoder.encode(fields: [:field1, :field2, relationship: [fields: [:field3]])

```

---

<div class="post-metadata">

**Author:** ![morfertaw](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/morfertaw/32/32062_2.png) [@morfertaw](https://forum.elixirforum.com/u/morfertaw)\
**Post date:** [October 4, 2023, 4:19am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/4 "2023-10-04T04:19:21Z")

</div>

Wow. This is great. I’m guessing the names are a little wrong. They should be.

```elixir
def encode(records, opts \\ []) do
  Jason.encode!(sanitize(records, opts))
end

defp sanitize(records, opts) when is_list(records) do
  Enum.map(records, &sanitize(&1, opts))
end

```

> [@zachdaniel](#):
>
> ```elixir
> def encode(resources, opts \\ []) do
> Jason.encode!(sanitize(resources, opts))
> end
> 
> defp sanitize(records, opts) when is_list(resources) do
> Enum.map(records, &sanitize(&1, opts))
> end
> 
> ```

Cheers!

---

<div class="post-metadata">

**Author:** ![vonagam](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/vonagam/32/33775_2.png) [@vonagam](https://forum.elixirforum.com/u/vonagam)\
**Post date:** [March 2, 2024, 5:39am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/5 "2024-03-02T05:39:07Z")

</div>

Alternative solution for those who stumble upon this thread:

Had the same use case with `live_svelte` and decided to go with more automatic approach by writing an Ash extension that defines customizable `Jason` implementation for a resource based on its fields - [`ash_jason`](https://github.com/vonagam/ash_jason).

To get some reasonable default behavior just include `AshJason.Extension` into `extensions` in `use Ash.Resource` call. To customize use optional `jason` section.

It is also possible to write your own extension using `ash_jason` as a reference point - the library is small, just around hundred lines between two files.

---

<div class="post-metadata">

**Author:** ![user20230119](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/user20230119/32/31375_2.png) [@user20230119](https://forum.elixirforum.com/u/user20230119)\
**Post date:** [March 30, 2025, 11:55am UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/6 "2025-03-30T11:55:14Z")

</div>

Is there a newer way to convert Ash resources to and from JSON?

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [March 30, 2025, 12:07pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/7 "2025-03-30T12:07:53Z")

</div>

The answer here really is “it depends”. A record can exist in many states, and in general it doesn’t always make sense to have one “this is how you turn it into JSON”. For example, you don’t necessarily want to encode _all loaded relationships_ every time, etc. So to really answer I’d have to know why you are encoding/decoding Ash resources to/from JSON 😃

---

<div class="post-metadata">

**Author:** ![user20230119](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/user20230119/32/31375_2.png) [@user20230119](https://forum.elixirforum.com/u/user20230119)\
**Post date:** [March 30, 2025, 12:47pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/8 "2025-03-30T12:47:00Z")

</div>

It would be just to edit the Resource as a JSON. I also want to replace MongoDB with PostgreSQL. I would migrate MongoDB documents to a JSON column in a table.

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [March 30, 2025, 1:05pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/9 "2025-03-30T13:05:23Z")

</div>

In general, “editing a resource as JSON” isn’t a super flexible concept. You’re altering the underlying data structure directly. If you model your data using embedded resources or map types etc. you can accomplish pretty much whatever you want.

Why do you want to be able to arbitrarily edit your data model as JSON? In general, application design (IMO) should be going through “actions” to edit data in defined and semantic ways, with validations etc. applied.

---

<div class="post-metadata">

**Author:** ![user20230119](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/user20230119/32/31375_2.png) [@user20230119](https://forum.elixirforum.com/u/user20230119)\
**Post date:** [March 30, 2025, 1:21pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/10 "2025-03-30T13:21:19Z")

</div>

I would want the JSON to go through actions to edit the data. Some users prefer taking JSON from a textarea to edit it in their editor instead of clicking around a form.

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [March 30, 2025, 2:06pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/11 "2025-03-30T14:06:04Z")

</div>

So with an “action” the concept is you have a contract of its interface. For example:

```elixir
update :increment_score do
  argument :amount, :integer, allow_nil?: false

  change atomic_update(:score, expr(score + ^arg(:amount)))
end

```

The only way to allow editing json one-to-one with the underlying data model is to effectively do away with that input/data model abstraction which is typically quite important. What you can do relatively safely however, is something like

```elixir
update :update do
  argument :stuff, <an embedded type, or a struct/map type w/ fields constraint>

  change fn changeset, _ -> 
    # decide what to do with the `:stuff` argument.
  end
end

```

Users could edit a specified type by you as JSON, and you can map it to its effects on the action. If the thing they are editing is just “a blob” of sorts then you can just write it directly to the corresponding attribute etc.

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [March 30, 2025, 2:07pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/12 "2025-03-30T14:07:31Z")

</div>

And, FWIW, if there is an attribute that is just a “user editable data model”,  
then you can do

```elixir
attributes do
  attribute :name, <# embedded type, or a struct/map type w/ fields constraint>
end

actions do
  update :update do
    accept [:name]
  end
end

```

If a map Is provided as input to `name` (i.e free form JSON data) it should “just work”.

---

<div class="post-metadata">

**Author:** ![user20230119](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/user20230119/32/31375_2.png) [@user20230119](https://forum.elixirforum.com/u/user20230119)\
**Post date:** [March 30, 2025, 8:30pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/13 "2025-03-30T20:30:09Z")

</div>

Could we also pass JSON to `AshPhoenix.Form.submit` or `Ash.Changeset.for_create` like `Ecto.Changeset.cast` that takes in a map with string keys?

---

<div class="post-metadata">

**Author:** ![zachdaniel](https://forum.elixirforum.com/user_avatar/forum.elixirforum.com/zachdaniel/32/31980_2.png) [@zachdaniel](https://forum.elixirforum.com/u/zachdaniel)\
**Post date:** [March 30, 2025, 10:06pm UTC](https://forum.elixirforum.com/t/serializing-ash-structs-with-jason/58654/14 "2025-03-30T22:06:29Z")

</div>

Yep 🙂 you can do that.